BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../scripts/build/ninja/copy.gni")
import("../scripts/build/typescript/typescript.gni")

group("test") {
  deps = [
    ":run",
    ":unittests",
    "e2e",
    "interactions",
    "perf",
    "shared",
  ]
}

group("unittests") {
  deps = [
    "../front_end:test_inputs",
    "../front_end:unittests",
    "../inspector_overlay:unittests",
    "shared",
    "unit:karma",
  ]
}

node_ts_library("run") {
  sources = [ "run.ts" ]

  deps = [ "shared" ]
}

source_root = rebase_path("//$devtools_location", target_gen_dir)
checkout_root = rebase_path("//", target_gen_dir)
build_root = rebase_path(root_build_dir, target_gen_dir)
write_file(
    "$target_gen_dir/build.js",
    "module.exports = {SOURCE_ROOT: '$source_root', CHECKOUT_ROOT: '$checkout_root', BUILD_ROOT: '$build_root', BUILD_WITH_CHROMIUM: $build_with_chromium};")