-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathfunctional-clojure-sequences.clj
501 lines (348 loc) · 10.2 KB
/
functional-clojure-sequences.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
;;;;
;;;; ____________________
;;;; < Functional Clojure >
;;;; --------------------
;;;; \ ^__^
;;;; \ (oo)\_______
;;;; (__)\ )\/\
;;;; ||----w |
;;;; || ||
;;;;
;;;; Functional clojure: sequences
;;;;
;;;; (c) 2011-2012 Joost Diepenmaat
;;;; Zeekat Softwareontwikkeling
;;;;
;;;; http://joost.zeekat.nl/
;;;; [email protected]
(ns user)
;;;;
;;;; Clojure basics that you need to know
;;;
(def my-keyword :a-keyword)
(def my-vector [:a :b :c 4 "some text"])
(my-vector 2)
(def my-map {:one 1
:two 2
:sentence "some sentence"})
(my-map :one)
(:one my-map)
(defn my-function
[arg1 arg2]
(+ (* arg1 arg2) 10))
(my-function 4 5)
(defn my-other-function
[arg1 arg2]
(arg1 (* 4 arg2) 10))
(my-other-function + 5)
;;;;
;;;; Some data
;;;;
(def items [{:name "car"
:wheels [:wheel1 :wheel2
:wheel3 :wheel4]}
{:name "bike"
:wheels [:bicycle-wheel-1
:bicycle-wheel-2]}
{:name "tricycle"
:wheels [:tricycle-wheel1
:tricycle-wheel2
:tricycle-wheel2]}
{:name "unicycle"
:wheels [:unicycle-wheel]}
{:name "dog"
:legs [:dog-leg1 :dog-leg2
:dog-leg3 :dog-leg4]}])
;;;;
;;;; What is a seq
;;;;
(seq? items) ; => false
;;;;
;;;; Clojure lists are seqs, but vectors, arrays, hash-maps any many
;;;; other things are not
;;;;
(seq? (list 1 2 3 4)) ; => true
(seq? [1 2 3 4]) ; => false
(seq? {:a 1 :b 2}) ; => false
;;;;
;;;; You can *make* a seq from many things
;;;;
(seq items) ; => ({:name "car", :wheels [:wheel1 :wheel2 :wheel3 :wheel4]} {:name "bike", :wheels [:bicycle-wheel-1 :bicycle-wheel-2]} {:name "tricycle", :wheels [:tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2]} {:name "unicycle", :wheels [:unicycle-wheel]} {:name "dog", :legs [:dog-leg1 :dog-leg2 :dog-leg3 :dog-leg4]})
(seq? (seq items)) ; => true
(seq {:name "value"
:stuff 2}) ; => ([:name "value"] [:stuff 2])
(seq #{:a :b 1 2}) ; => (1 2 :a :b)
;;;;
;;;; So what is a seq?
;;;;
;;;;
;;;; What is a list?
;;;;
;;;; Cell Cell Cell Cell
;;;; +-+-+ +-+-+ +-+-+ +-+-+
;;;; |*|*+--> |*|*+--> |*|*+--> |*|*+--> ..
;;;; +++-+ +++-+ +++-+ +++-+
;;;; | | | |
;;;; V V V V
;;;; value value value value
(def v1 :my-value)
(def v2 :another-value)
(def lst (list 1 2 3 4))
(cons v1 lst) ; => (:my-value 1 2 3 4)
(cons v1 (cons v2 lst)) ; => (:my-value :another-value 1 2 3 4)
;;;;
;;;; Seqs are *abstractions* that act like immutable linked lists
;;;;
;;;; Cell Cell Cell Cell
;;;; +-+-+ +-+-+ +-+-+ +-+-+
;;;; |*|*+--> |*|*+--> |*|*+--> |*|*+--> ..
;;;; +++-+ +++-+ +++-+ +++-+
;;;; | | | |
;;;; V V V V
;;;; value value value value
;;;;
;;;; What does a seq provide
;;;;
(def short-list (list :a :b :c))
(first short-list) ; => :a
(rest short-list) ; => (:b :c)
(next short-list) ; => (:b :c)
(cons :d short-list) ; => (:d :a :b :c)
(rest '(:a)) ; => ()
(next '(:a)) ; => nil
(next ()) ; => nil
(rest ()) ; => ()
;; But do not think too hard about rest vs next right now
;; when in doubt, use next
;;;;
;;;; Seq to collections
;;;;
(def s (seq [1 2 3 4 5 6])) ; => #'user/s
;; Direct constructors
(vec s) ; => [1 2 3 4 5 6]
(set s) ; => #{1 2 3 4 5 6}
;; conj into an existing collection
(into [] s) ; => [1 2 3 4 5 6]
(into #{} s) ; => #{1 2 3 4 5 6}
(into {} (seq [[:a 1] [:b 2]])) ; => {:a 1, :b 2}
;; but note:
(into '() s) ; => (6 5 4 3 2 1)
;;;;
;;;; `seq` on empty collections returns nil
;;;;
(seq? ())
(seq nil) ; => nil
(seq ()) ; => nil
(seq []) ; => nil
(seq {}) ; => nil
(seq #{}) ; => nil
;;;;
;;;; Making a seq from a seq
;;;;
;; reminder:
(def items [{:name "car"
:wheels [:wheel1 :wheel2
:wheel3 :wheel4]}
{:name "bike"
:wheels [:bicycle-wheel-1
:bicycle-wheel-2]}
{:name "tricycle"
:wheels [:tricycle-wheel1
:tricycle-wheel2
:tricycle-wheel2]}
{:name "unicycle"
:wheels [:unicycle-wheel]}
{:name "dog"
:legs [:dog-leg1 :dog-leg2
:dog-leg3 :dog-leg4]}])
;;;;
;;;; what does this do?
;;;;
((fn self [coll]
(and (seq coll)
(cons (:name (first coll))
(self (next coll)))))
items) ; => ("car" "bike" "tricycle" "unicycle" "dog")
;;;;
;;;; what does this do?
;;;;
((fn self [coll]
(and (seq coll)
(cons (:name (first coll))
(self (next coll)))))
items)
;;;; seems like a lot of boiler plate
;;;; when we just want to extract the names
;;;;
;;;; solution: take a function as an argument
;;;;
((fn self [f coll]
(and (seq coll)
(cons (f (first coll))
(self f (next coll)))))
(fn [i] (:name i)) ; f argument
items) ; => ("car" "bike" "tricycle" "unicycle" "dog")
;;;;
;;;; solution: take a function as an argument
;;;;
((fn self [f coll]
(and (seq coll)
(cons (f (first coll))
(self f (next coll)))))
(fn [i] (:name i))
items)
;; problem:
;; still uses stack space proportional to (count coll)
;;;;
;;;; solution: use lazy-seq.
;;;;
((fn self [f coll]
(lazy-seq (and (seq coll)
(cons (f (first coll))
(self f (next coll))))))
(fn [i] (:name i))
items)
;;;;
;;;; solution: use lazy-seq.
;;;;
((fn self [f coll]
(lazy-seq (and (seq coll)
(cons (f (first coll))
(self f (next coll))))))
(fn [i] (:name i))
items)
;;;; which is basically, map:
(map (fn [item]
(:name item))
items) ; => ("car" "bike" "tricycle" "unicycle" "dog")
;;;;
;;;; solution: use lazy-seq.
;;;;
((fn self [f coll]
(lazy-seq (and (seq coll)
(cons (f (first coll))
(self f (next coll))))))
(fn [i] (:name i))
items)
;;;; which is basically, map:
(map (fn [item]
(:name item))
items)
;;;; let's shorten that a bit
(map #(:name %)
items)
;;;;
;;;; solution: use lazy-seq.
;;;;
((fn self [f coll]
(lazy-seq (and (seq coll)
(cons (f (first coll))
(self f (next coll))))))
(fn [i] (:name i))
items)
;;;; which is basically, map:
(map (fn [item]
(:name item))
items)
;;;; let's shorten that a bit
(map #(:name %)
items)
;;;; but keywords are already functions!
(:key {:key :value}) ; => :value
(map :name items)
;;;;
;;;; What else can we do with seqs
;;;;
;; get all the things with wheels:
(filter :wheels items) ; => ({:name "car", :wheels [:wheel1 :wheel2 :wheel3 :wheel4]} {:name "bike", :wheels [:bicycle-wheel-1 :bicycle-wheel-2]} {:name "tricycle", :wheels [:tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2]} {:name "unicycle", :wheels [:unicycle-wheel]})
;; or
(keep :wheels items) ; => ([:wheel1 :wheel2 :wheel3 :wheel4] [:bicycle-wheel-1 :bicycle-wheel-2] [:tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2] [:unicycle-wheel])
;;;; get all the thing WITHOUT wheels:
(remove :wheels items) ; => ({:name "dog", :legs [:dog-leg1 :dog-leg2 :dog-leg3 :dog-leg4]})
;;;;
;;;; get all the wheels as a single seq:
;;;;
(mapcat :wheels items) ; => (:wheel1 :wheel2 :wheel3 :wheel4 :bicycle-wheel-1 :bicycle-wheel-2 :tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2 :unicycle-wheel)
;;;;
;;;; get everything with more than 2 wheels:
;;;;
(filter #(< 2 (count (:wheels %))) items) ; => ({:name "car", :wheels [:wheel1 :wheel2 :wheel3 :wheel4]} {:name "tricycle", :wheels [:tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2]})
;;;;
;;;; sort items by number of wheels (ascending)
;;;;
(sort [6 2 8 10]) ; => (2 6 8 10)
(defn wheel-count
[item]
(count (:wheels item)))
(sort-by wheel-count items) ; => ({:name "dog", :legs [:dog-leg1 :dog-leg2 :dog-leg3 :dog-leg4]} {:name "unicycle", :wheels [:unicycle-wheel]} {:name "bike", :wheels [:bicycle-wheel-1 :bicycle-wheel-2]} {:name "tricycle", :wheels [:tricycle-wheel1 :tricycle-wheel2 :tricycle-wheel2]} {:name "car", :wheels [:wheel1 :wheel2 :wheel3 :wheel4]})
;;;;
;;;; sort descending
;;;;
(defn reverse-compare
[a b]
(compare b a))
(sort-by wheel-count reverse-compare items)
;;;;
;;;; some infinite sequences
;;;;
(take 10 (repeatedly rand)) ; => (0.6121773318782444 0.19423236761108165 0.8850590126241661 0.2166941331273856 0.9595494895081473 0.5251935455837357 0.3684493851601529 0.5340716398033004 0.9248327915320852 0.7105046471052063)
(take 10 (repeat 4)) ; => (4 4 4 4 4 4 4 4 4 4)
(take 10 (iterate inc 0)) ; => (0 1 2 3 4 5 6 7 8 9)
(take 10 (cycle [1 2 3 4])) ; => (1 2 3 4 1 2 3 4 1 2)
;; and ranges
(range 10) ; => (0 1 2 3 4 5 6 7 8 9)
(range 10 0 -1) ; => (10 9 8 7 6 5 4 3 2 1)
;;;;
;;;; Summarize a seq:
;;;;
;;;; Turn a seq into a "single value"
;;;;
;;;;
;;;; does every item have legs?
;;;;
(every? :legs items) ; note: predicate names end with "?"
;;;;
;;;; are there things with legs?
;;;;
(some :legs items) ; => [:dog-leg1 :dog-leg2 :dog-leg3 :dog-leg4]
;;;;
;;;; also..
;;;;
(not-every? :legs items) ; => true
(not-any? :antennea items) ; => true
;;;;
;;;; count the wheels. note: (count nil) = 0
;;;;
(reduce + 3 [1 2 3 4]) ; => 13
(reduce conj () (list 1 2 3 4)) ; => (4 3 2 1)
(reduce #(+ %1 (count (:wheels %2))) 0 items)
;; or
(reduce + (map #(count (:wheels %)) items))
;; or
(reduce + (map count (map :wheels items)))
;; or
(reduce + (map wheel-count items))
;;;;
;;;; Some notes
;;;;
;; all of the shown functions are just functions written in pure
;; clojure
;; you can write your own variants and you don't even need macros to
;; do it
;; pmap does map in parallel
;; your performance may vary
;; this presentation is just a clojure source file
;;;;
;;;; _________
;;;; < The End >
;;;; ---------
;;;; \ ^__^
;;;; \ (oo)\_______
;;;; (__)\ )\/\
;;;; ||----w |
;;;; || ||
;;;;
;;;; Functional clojure: sequences
;;;;
;;;; http://joost.zeekat.nl/
;;;; [email protected]