settings.gradle

plugins {
    id 'com.gradle.develocity' version '3.19.1'
    id 'com.gradle.common-custom-user-data-gradle-plugin' version '2.1'
}

def isCI = System.getenv('CI') != null
def isLocal = !isCI
def isAuthenticated = System.getenv('DEVELOCITY_ACCESS_KEY') != null

develocity {
    server = 'https://ge.grails.org'
    buildScan {
        tag('grails')
        tag('grails-data-mapping')
        publishing.onlyIf { isAuthenticated }
        uploadInBackground = isLocal
    }
}

buildCache {
    local { enabled = isLocal }
    remote(develocity.buildCache) {
        push = isCI && isAuthenticated
        enabled = true
    }
}

rootProject.name = 'grails-data-mapping'

include(
    'grails-datastore-core',
    'grails-datastore-web',

    // Core GORM Implementation projects
    'grails-datastore-gorm',
    'grails-datastore-async',
    'grails-datastore-gorm-async',
    'grails-datastore-gorm-validation',
    'grails-datastore-gorm-support',
    'grails-datastore-gorm-tck',
    'grails-datastore-gorm-test',

    // RX projects
    // until this can be finished ported to grails 7, we are disabling
    //'grails-datastore-gorm-rx',

    // Testing Support
    'grails-gorm-testing-support',

    // Test Report
    'test-report'
)

// Documentation
include 'docs-guide-developer'
project(':docs-guide-developer').projectDir = file('docs/guide-developer')

// until this can be finished ported to grails 7, we are disabling
//include 'docs-guide-rx'
//project(':docs-guide-rx').projectDir = file('docs/guide-rx')

include 'docs-guide-whats-new'
project(':docs-guide-whats-new').projectDir = file('docs/guide-whats-new')