forked from scuptio/tlaplus-specification
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathraft.tla
1664 lines (1490 loc) · 60.7 KB
/
raft.tla
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
--------------------------------- MODULE raft ---------------------------------
EXTENDS
action,
raft_common,
raft_replicate_common,
history,
Naturals,
FiniteSets,
Sequences,
Integers,
TLC
CONSTANT VALUE
CONSTANT NODE_ID
CONSTANT MAX_TERM
CONSTANT CHECK_SAFETY
CONSTANT ENABLE_ACTION
CONSTANT DB_INIT_STATE_PATH
CONSTANT DB_SAVE_STATE_PATH
CONSTANT DB_ACTION_PATH
CONSTANT APPEND_ENTRIES_MAX
CONSTANT VOTE
CONSTANT REPLICATE
CONSTANT RESTART
CONSTANT RECONFIG
CONSTANT CLIENT_REQUEST
----
VARIABLE v_role
VARIABLE v_log
VARIABLE v_voted_for
VARIABLE v_snapshot
VARIABLE v_commit_index
VARIABLE v_acked_value
VARIABLE v_messages
VARIABLE v_current_term
VARIABLE v_conf_committed
VARIABLE v_conf_new
VARIABLE v_follower_vote_granted
VARIABLE v_follower_next_index
VARIABLE v_follower_match_index
VARIABLE v_follower_conf
VARIABLE v_follower_term_commit_index
VARIABLE v_history
VARIABLE __action__
VARIABLE v_cnt_limit
TERM_VALUE == Nat
vars_config == <<
v_conf_committed,
v_conf_new,
v_follower_conf,
v_follower_term_commit_index
>>
vars_leader == <<
v_follower_vote_granted,
v_follower_next_index,
v_follower_match_index,
v_follower_conf,
v_follower_term_commit_index
>>
vars_control == <<v_cnt_limit>>
vars == <<
v_role,
v_current_term,
v_log,
v_voted_for,
v_snapshot,
v_commit_index,
v_follower_next_index,
v_follower_match_index,
v_follower_vote_granted,
v_messages,
v_history,
v_acked_value,
v_conf_committed,
v_conf_new,
v_follower_conf,
v_follower_term_commit_index,
__action__,
vars_control
>>
vars_view == <<
v_role,
v_current_term,
v_log,
v_voted_for,
v_snapshot,
v_commit_index,
v_follower_next_index,
v_follower_match_index,
v_follower_vote_granted,
v_conf_committed,
v_conf_new,
v_follower_conf,
v_follower_term_commit_index,
v_messages
>>
vars_hard_state == <<
v_current_term,
v_log,
v_voted_for,
v_snapshot
>>
vars_except_action_and_pc == <<
vars_hard_state,
v_role,
v_commit_index,
v_follower_next_index,
v_follower_match_index,
v_follower_vote_granted,
v_messages,
v_history,
v_acked_value
>>
vars_except_action == <<
vars_hard_state,
v_role,
v_commit_index,
v_follower_next_index,
v_follower_match_index,
v_acked_value,
v_follower_vote_granted,
v_messages,
v_history
>>
vars_vote == <<v_follower_vote_granted>>
vars_replicate == <<v_commit_index, v_follower_next_index, v_follower_match_index, v_acked_value>>
_RaftVariables(_nid) ==
[
role |-> v_role[_nid],
current_term |-> v_current_term[_nid],
log |-> v_log[_nid],
snapshot |-> v_snapshot[_nid],
voted_for |-> v_voted_for[_nid],
commit_index |-> v_commit_index[_nid],
conf_committed |-> v_conf_committed[_nid],
conf_new |-> v_conf_new[_nid],
follower_vote_granted |-> v_follower_vote_granted[_nid],
follower_next_index |-> v_follower_next_index[_nid],
follower_match_index |-> v_follower_match_index[_nid],
follower_term_commit_index |-> v_follower_term_commit_index[_nid],
follower_conf |-> v_follower_conf[_nid]
]
ActionCheckState(_node_id) ==
ActionsFromHandle(
_RaftVariables,
{_node_id},
ActionInput,
__ActionCheck
)
InitActionSeqSetup(_node_id) ==
ActionsFromHandle(
_RaftVariables,
_node_id,
ActionInput,
__ActionInit
)
ActionSeqSetupAll(_node_id) ==
ActionsFromHandle(
_RaftVariables,
_node_id,
ActionInput,
__ActionInit
)
SaveVars ==
[
role |-> v_role,
current_term |-> v_current_term,
log |-> v_log,
snapshot |-> v_snapshot,
voted_for |-> v_voted_for,
commit_index |-> v_commit_index,
conf_committed |-> v_conf_committed,
conf_new |-> v_conf_new
]
SaveStates ==
DB_SAVE_STATE_PATH /= "" =>
SaveValue(SaveVars, DB_SAVE_STATE_PATH)
SaveActions ==
DB_ACTION_PATH /= "" =>
SaveValue(__action__, DB_ACTION_PATH)
SaveInitActions ==
DB_ACTION_PATH /= "" =>
SaveValue(__action__, DB_ACTION_PATH)
CntAppendLog == "App"
CntHandleAppendReq == "HAppReq"
CntHandleAppendResp == "HAppResp"
CntLogCompaction == "LogComp"
CntHandleApplyReq == "HAplReq"
CntHandleApplyResp == "HAplResp"
CntVoteReq == "Vote"
CntHandleVoteReq == "HVoteReq"
CntHandleVoteResp == "HVoteResp"
CntRestart == "Restart"
CntClientReq == "ClientReq"
CntTickUpConf == "TickUpConfReq"
CntHandleUpConfReq == "HUpConfReq"
CntHandleUpConfResp == "HUpConfResp"
CntReConfBegin == "ReConfBegin"
CntReConfCommit == "ReConfCommit"
CntLimitDomain == {
CntAppendLog,
CntHandleAppendReq,
CntHandleAppendResp,
CntLogCompaction,
CntHandleApplyReq,
CntHandleApplyResp,
CntClientReq,
CntRestart,
CntVoteReq,
CntHandleVoteReq,
CntHandleVoteResp,
CntTickUpConf,
CntHandleUpConfReq,
CntHandleUpConfResp,
CntReConfBegin,
CntReConfCommit
}
_ConfTermIndex(
_term,
_index
) ==
[
term |-> _term,
index |-> _index
]
_Init(
_node_id,
_value,
_enable_state_db,
_enable_action,
_state_db_path
)
==
/\ IF _enable_state_db THEN
\* read initial state from database
LET all_state_set == QueryAllValues(_state_db_path)
IN \E all_state \in all_state_set:
(LET node_ids_has_state == DOMAIN all_state.role
e == InitStateSetup(
_node_id \ node_ids_has_state, node_ids_has_state, all_state, _value)
IN /\ v_role = e.role
/\ v_current_term = e.current_term
/\ v_log = e.log
/\ v_snapshot = e.snapshot
/\ v_voted_for = e.voted_for
/\ v_commit_index = e.commit_index
/\ v_conf_committed = e.conf_committed
/\ v_conf_new = e.conf_new
)
ELSE
\* build initial state
LET e == InitStateSetup(_node_id, {}, NULL, _value)
IN /\ v_role = e.role
/\ v_current_term = e.current_term
/\ v_log = e.log
/\ v_snapshot = e.snapshot
/\ v_voted_for = e.voted_for
/\ v_commit_index = e.commit_index
/\ v_conf_committed = e.conf_committed
/\ v_conf_new = e.conf_new
/\ v_messages = {}
/\ v_history = <<>>
/\ v_acked_value = {}
/\ v_follower_next_index = [i \in _node_id |-> [j \in NODE_ID |-> 1]]
/\ v_follower_match_index = [i \in _node_id |-> [j \in NODE_ID |-> 0]]
/\ v_follower_vote_granted = [i \in _node_id |-> [j \in NODE_ID |-> 0]]
/\ v_follower_conf = [i \in _node_id |-> [j \in _node_id |-> [conf_committed |-> _ConfVersion(0, 0, 0), conf_new |-> _ConfVersion(0, 0, 0)]]]
/\ v_follower_term_commit_index = [i \in _node_id |-> [j \in _node_id |-> _ConfTermIndex(0, 0)]]
/\ v_cnt_limit = [i \in CntLimitDomain |-> 0]
/\ LET actions == InitActionSeqSetup(_node_id)
IN __action__ = InitAction(
actions,
actions,
_enable_action
)
_ConfigQuorumCheck(
_leader,
_config_term,
_config_version,
_config_node,
_follower_conf,
_check_conf_new
) ==
/\ _leader \in _config_node
/\ \E Q \in QuorumOf(_config_node):
/\ _leader \in Q
/\ \A j \in Q \ {_leader}:
/\ _follower_conf[j] /= NULL
/\ IF _check_conf_new THEN
/\ _follower_conf[j].conf_new.version = _config_version
/\ _follower_conf[j].conf_new.term = _config_term
ELSE
/\ _follower_conf[j].conf_committed.version = _config_version
/\ _follower_conf[j].conf_committed.term = _config_term
_TermCommitIndexQuorumCheck(
_leader,
_leader_term,
_conf_new,
_follower_term_cindex
) ==
/\ _conf_new /= NULL
/\ _leader \in _conf_new.nid_vote
/\ \E Q \in QuorumOf(_conf_new.nid_vote):
/\ _leader \in Q
/\ \A j \in Q \ {_leader}:
/\ _follower_term_cindex[j].term = _leader_term
/\ _follower_term_cindex[j].index >= _conf_new.conf_version.index
_QuorumOverlapped(_node_set1, _node_set2) ==
\A q1 \in QuorumOf(_node_set1), q2 \in QuorumOf(_node_set2):
q1 \cap q2 /= {}
_ConfigNew(_conf_committed, _conf_new, _i) ==
IF _conf_new[_i] /= NULL THEN
_conf_committed[_i]
ELSE
_conf_new[_i]
LastEntryIndex(_log, _next_index, i, j) ==
Min({
IF Len(_log[i]) > 0 THEN
_log[i][Len(_log[i])].index
ELSE
0,
_next_index[i][j]
})
PrevLogIndex(_next_index, i, j) ==
IF _next_index[i][j] > 0 THEN
_next_index[i][j] - 1
ELSE
0
_IndexTermOfSnapshotEntries(_entries) ==
IF Cardinality(_entries) = 0 THEN
[begin_index |-> 0, end_index |-> 0, index |-> 0, term |-> 0]
ELSE
LET begin_e == CHOOSE e \in _entries:
~(\E _e \in _entries:
_e.index < e.index
)
end_e == CHOOSE e \in _entries:
~(\E _e \in _entries:
_e.index > e.index
)
IN \* [begin_index, end_index] , minimum, maximum index pair
[begin_index |-> begin_e.index, end_index |-> end_e.index, index |-> end_e.index, term |-> end_e.term]
MessageApplySnapshot(
_source,
_dest,
_term,
_snapshot
) ==
LET index_term == _IndexTermOfSnapshotEntries(_snapshot.entries)
IN
Message(_source, _dest, ApplyReq,
[
term |-> _term,
id |-> "",
begin_index |-> index_term.begin_index,
end_index |-> index_term.end_index,
snapshot |-> _snapshot
]
)
\* TLA+ {D240422N-MsgUpdateConfReq}
MsgUpdateConfReq(
_source,
_dest,
_term,
_conf_committed,
_conf_new
) ==
Message(_source, _dest, UpdateConfigReq,
[
term |-> _term,
conf_committed |-> _conf_committed,
conf_new |-> _conf_new
]
)
\* TLA+ {D240422N-MsgUpdateConfResp}
MsgUpdateConfResp(
_source,
_dest,
_term,
_conf_committed,
_conf_new
) ==
Message(_source, _dest, UpdateConfigResp,
[
term |-> _term,
conf_committed |-> _conf_committed,
conf_new |-> _conf_new
]
)
_UpdateTerm(_node_id, _term) ==
IF _term > v_current_term[_node_id] THEN
[state |-> Follower, current_term |-> _term, voted_for |-> INVALID_NODE_ID]
ELSE
[state |-> v_role[_node_id], current_term |-> v_current_term[_node_id], voted_for |-> v_voted_for[_node_id]]
_ConfigVersionLess(_c1, _c2) ==
\/ _c1.term < _c2.term
\/ (/\ _c1.term = _c2.term
/\ _c1.version < _c2.version
)
\* TLA+ {D240504N-MsgAppendRequest}
MsgAppendRequest(
_source,
_dest,
_term,
_prev_log_index,
_prev_log_term,
_log_entries,
_commit_index,
_leader_log,
_leader_snapshot,
_aux_payload
) ==
LET payload ==
IF _aux_payload THEN
[
term |-> _term,
prev_log_index |-> _prev_log_index,
prev_log_term |-> _prev_log_term,
log_entries |-> _log_entries,
commit_index |-> _commit_index,
\* only valid for checking safty invariant
leader_log |-> _leader_log,
leader_snapshot |-> _leader_snapshot
]
ELSE
[
term |-> _term,
prev_log_index |-> _prev_log_index,
prev_log_term |-> _prev_log_term,
log_entries |-> _log_entries,
commit_index |-> _commit_index
]
IN Message(_source, _dest, AppendRequest, payload)
_AppendRequestMessages(
_log,
_next_index,
_commit_index,
_current_term,
_snapshot,
_append_max,
_source,
_dest,
_check_safety
) ==
LET prev_log_index == PrevLogIndex(_next_index, _source, _dest)
IN IF prev_log_index < _snapshot[_source].index THEN (
LET apply_message == MessageApplySnapshot(
_source,
_dest,
_current_term[_source],
_snapshot[_source])
IN apply_message
)
ELSE (
LET prev_log_term == LogTerm(
_log,
_snapshot,
_source,
prev_log_index)
\* Send up to APPEND_ENTRIES_MAX entries, constrained by the end of the r_log[i].
entries == LogEntries(
_log,
_snapshot,
_source,
prev_log_index + 1,
_append_max)
commit_index == _commit_index[_source]
append_message == MsgAppendRequest(
_source, \*_source,
_dest, \*_dest,
_current_term[_source], \* _term,
prev_log_index, \* _prev_log_index,
prev_log_term, \* _prev_log_term,
entries, \* _log_entries,
commit_index, \* _commit_index,
_log[_source], \* _leader_log,
_snapshot[_source], \* _leader_snapshot,
_check_safety \* _aux_payload
)
IN append_message
) \* end else
AppendRequestMessages(
_log,
_next_index,
_commit_index,
_current_term,
_snapshot,
_append_max,
_source,
servers, msgs,
_check_safety
) ==
LET f == [dest \in servers \ {_source} |->
_AppendRequestMessages(
_log,
_next_index,
_commit_index,
_current_term,
_snapshot,
_append_max,
_source,
dest,
_check_safety
)
]
IN {f[id] : id \in DOMAIN f}
UpdateAckedValues(
_log,
_snapshot,
index,
_check_safety
) ==
IF _check_safety THEN
v_acked_value' = v_acked_value \cup AllValuesLEIndex(_log, _snapshot, index, VALUE)
ELSE
UNCHANGED <<v_acked_value>>
_BecomeLeader(
_node_id,
_v_current_term,
_v_role,
_v_follower_next_index,
_v_follower_match_index,
_v_commit_index,
_v_log,
_v_snapshot,
_v_history,
_check_safety
)==
/\ LET o ==
[
election |->
[
leader |-> _node_id,
term |-> _v_current_term[_node_id],
log |-> _v_log[_node_id],
snapshot |-> _v_snapshot[_node_id]
]
]
IN _v_history' = AppendHistory(_v_history, o, _check_safety)
/\ v_role' = [v_role EXCEPT ![_node_id] = Leader]
/\ LET last_log_index == LastLogIndex(_v_log[_node_id], _v_snapshot[_node_id])
IN _v_follower_next_index' = [_v_follower_next_index EXCEPT ![_node_id] = [j \in NODE_ID |-> last_log_index + 1]]
/\ _v_follower_match_index' = [_v_follower_match_index EXCEPT ![_node_id] = [j \in NODE_ID |-> _v_snapshot[_node_id].index]]
/\ _v_commit_index' = [_v_commit_index EXCEPT ![_node_id] = _v_snapshot[_node_id].index]
_ClearLeaderVar(_nid, _nid_set) ==
/\ v_follower_vote_granted' = [v_follower_vote_granted EXCEPT ![_nid] = [j \in _nid_set |-> 0]]
/\ v_follower_next_index' = [v_follower_next_index EXCEPT ![_nid] = [j \in _nid_set |-> 1]]
/\ v_follower_match_index' = [v_follower_match_index EXCEPT ![_nid] = [j \in _nid_set |-> 0]]
/\ v_commit_index' = [v_commit_index EXCEPT ![_nid] = v_snapshot[_nid].index]
/\ v_follower_term_commit_index' = [v_follower_term_commit_index EXCEPT ![_nid] = [j \in _nid_set |-> [term |-> 0, index |-> 0]]]
/\ v_follower_conf' = [v_follower_conf EXCEPT ![_nid] = [j \in _nid_set |->
[conf_committed |-> _ConfVersion(0, 0, 0), conf_new |-> _ConfVersion(0, 0, 0)]
]]
_UnchangedLeaderVar(_nid) ==
/\ UNCHANGED <<v_follower_vote_granted, v_follower_match_index, v_commit_index, v_follower_term_commit_index, v_follower_conf>>
\* NODE_ID _node_id times out and starts a new election.
VoteRequestVote(_node_id, _max_term, _check_safety, _node_id_set, _enable_action) ==
/\ _node_id \in v_conf_committed[_node_id].nid_vote
/\ _node_id \in v_conf_new[_node_id].nid_vote
/\ TermLE(_node_id, v_current_term, _max_term)
/\ v_role[_node_id] = Follower
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = v_current_term[_node_id] + 1]
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = _node_id]
/\ LET nodes == v_conf_committed[_node_id].nid_vote \cup v_conf_new[_node_id].nid_vote
IN (
/\ IF {_node_id} = nodes THEN
_BecomeLeader(
_node_id,
v_current_term',
v_role,
v_follower_next_index,
v_follower_match_index,
v_commit_index,
v_log,
v_snapshot,v_history, _check_safety)
ELSE /\ v_role' = [v_role EXCEPT ![_node_id] = Candidate]
/\ UNCHANGED <<v_history, v_follower_match_index, v_follower_next_index, v_commit_index>>
/\ v_follower_vote_granted' = [v_follower_vote_granted EXCEPT ![_node_id][_node_id] = v_current_term'[_node_id]]
/\ LET payload == [
term |-> v_current_term[_node_id] + 1,
last_log_term |-> LastLogTerm(v_log[_node_id], v_snapshot[_node_id]),
last_log_index |-> LastLogIndex(v_log[_node_id], v_snapshot[_node_id])
]
messages == MessageSet({_node_id}, nodes \ {_node_id}, VoteRequest, payload)
actions_input == Action(ActionInput, MessageNP(_node_id, _node_id, __ActionRequestVote))
actions_output == Actions(ActionOutput, messages)
actions0 == ActionCheckState(_node_id)
actions == ActionSeqSetupAll(_node_id_set)
IN /\ v_messages' = WithMessageSet(messages, v_messages)
/\ SetAction(__action__, actions, actions0 \o actions_input \o actions_output, _enable_action)
)
/\ UNCHANGED <<
v_log,
v_snapshot,
v_acked_value,
vars_config
>>
__HandleVoteRequest(_node_id, _from_node_id, _msg_payload, action, _node_id_set, _enable_action) ==
LET term_context == _UpdateTerm(_node_id, _msg_payload.term)
last_log_term == _msg_payload.last_log_term
last_log_index == _msg_payload.last_log_index
grant == VoteCanGrant(
term_context.current_term,
v_log[_node_id],
v_snapshot[_node_id],
term_context.voted_for,
_from_node_id,
_msg_payload.term,
_msg_payload.last_log_term,
_msg_payload.last_log_index)
payload == [
term |-> term_context.current_term,
vote_granted |-> grant
]
a1 == action
reply == Message(_node_id, _from_node_id, VoteResponse, payload)
a2 == Action(ActionOutput, reply)
actions == ActionSeqSetupAll(_node_id_set)
IN /\ (\/ (/\ grant
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = _from_node_id]
/\ v_role' = [v_role EXCEPT ![_node_id] = term_context.state]
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = term_context.current_term]
)
\/ (/\ ~grant
/\ v_role' = [v_role EXCEPT ![_node_id] = term_context.state]
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = term_context.voted_for]
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = term_context.current_term]
)
)
/\ SetAction(__action__, actions, a1 \o a2, _enable_action)
/\ v_messages' = WithMessage(reply, v_messages)
/\ UNCHANGED <<
v_follower_vote_granted,
v_log,
v_snapshot,
v_history,
vars_config
>>
\* NODE_ID i receives a RequestVote response from server j with
\* m.term = v_current_term[i].
__HandleVoteResponse(i, _from_node, _m, _actions, _check_safety, _node_id, _enable_action) ==
/\ LET actions == ActionSeqSetupAll(_node_id)
IN
IF _m.term = v_current_term[i] THEN
/\ v_role[i] \in {Candidate, Leader}
/\ (\/( /\ _m.vote_granted
/\ v_follower_vote_granted' = [v_follower_vote_granted EXCEPT ![i][_from_node] = _m.term]
/\ IF /\ v_role[i] = Candidate
/\ LET granted_set == { j \in _node_id : v_follower_vote_granted'[i][j] = v_current_term[i] } \cup {i}
IN /\ granted_set \in QuorumOf(v_conf_committed[i].nid_vote)
/\ (\/ v_conf_new[i] = v_conf_committed[i]
\/ granted_set \in QuorumOf(v_conf_new[i].nid_vote)
)
THEN
( _BecomeLeader(
i,
v_current_term,
v_role,
v_follower_next_index,
v_follower_match_index,
v_commit_index,
v_log,
v_snapshot,v_history, _check_safety)
/\ SetAction(__action__, actions, _actions, _enable_action)
/\ UNCHANGED <<v_voted_for, v_current_term>>
)
ELSE
/\ SetAction(__action__, actions, _actions, _enable_action)
/\ UNCHANGED <<
v_role, v_voted_for, v_current_term,
v_follower_next_index, v_follower_match_index, v_commit_index, v_history>>
)
\/ ( /\ ~_m.vote_granted
/\ SetAction(__action__, actions, _actions, _enable_action)
/\ UNCHANGED <<
v_role, v_voted_for, v_current_term, v_follower_vote_granted,
v_follower_next_index, v_follower_match_index, v_commit_index, v_history>>
)
)
ELSE
/\ LET term_context == _UpdateTerm(i, _m.term)
IN (/\ v_role' = [v_role EXCEPT ![i] = term_context.state]
/\ v_voted_for' = [v_voted_for EXCEPT ![i] = term_context.voted_for]
/\ v_current_term' = [v_current_term EXCEPT ![i] = term_context.current_term]
)
/\ UNCHANGED <<v_follower_vote_granted, v_follower_next_index, v_commit_index, v_follower_match_index, v_history>>
/\ SetAction(__action__, actions, _actions, _enable_action)
/\ UNCHANGED <<v_log, v_snapshot, vars_config>>
\* Leader i sends j an AppendEntries request containing up to 1 entry.
\* While implementations may want to send more than 1 at a time, this spec uses
\* just 1 because it minimizes atomic regions without loss of generality.
AppendLogEntries(i, _append_entries_max, _check_safety, _node_id, _enalbe_action) ==
/\ v_role[i] = Leader
/\ LET node_ids == v_conf_committed[i].nid_log \cup v_conf_new[i].nid_log
n == _append_entries_max
msgs == AppendRequestMessages(
v_log, v_follower_next_index,
v_commit_index,
v_current_term,
v_snapshot,
n,
i, node_ids \ {i}, {}, _check_safety)
actions0 == ActionSeqSetupAll(_node_id)
actions1 == ActionCheckState(i)
actions2 == Action(ActionInput, MessageLocalNP(i, __ActionAppendLog))
actions3 == Actions(ActionOutput, msgs)
IN /\ v_messages' = WithMessageSet(msgs, v_messages)
/\ SetAction(__action__, actions0, actions1 \o actions2 \o actions3, _enalbe_action)
/\ UNCHANGED <<
v_commit_index,
v_current_term, v_role,
v_voted_for, v_snapshot, v_log,
v_history,
v_follower_match_index,
v_follower_next_index,
v_acked_value
>>
/\ UNCHANGED <<vars_vote, vars_config>>
_HandleAppendLog(
_node_id,
_from_node_id,
_payload,
_setup_action,
_input_action,
_check_safety,
_enable_action
) ==
LET term_context == _UpdateTerm(_node_id, _payload.term)
current_term == term_context.current_term
current_state == term_context.state
current_voted_for == term_context.voted_for
prev_log_index == _payload.prev_log_index
prev_log_term ==_payload.prev_log_term
log_ok == LogPrevEntryOK(
v_log[_node_id],
v_snapshot[_node_id],
prev_log_index,
prev_log_term)
term == _payload.term
log_entries == _payload.log_entries
commit_index == _payload.commit_index
result == HandleAppendLogInner(
_node_id,
v_log[_node_id],
v_snapshot[_node_id],
current_term,
current_state,
v_history,
_from_node_id,
prev_log_index,
prev_log_term,
term,
log_entries
)
action_handle_append == _input_action
IN /\ (CASE result.append_result = APPEND_RESULT_REJECT -> (
/\ LET next_index ==
(IF v_snapshot[_node_id].index > prev_log_index THEN
v_snapshot[_node_id].index
ELSE
0
)
reply_payload == [
term |-> current_term,
append_success |-> FALSE,
commit_index |-> 0,
match_index |-> 0,
next_index |-> next_index \* only when reject, tell leader the correct next index
]
reply_message == Message(_node_id, _from_node_id, AppendResponse, reply_payload)
output_action == Action(ActionOutput, reply_message)
IN /\ v_messages' = WithMessage(reply_message, v_messages)
/\ SetAction(__action__, _setup_action, action_handle_append \o output_action, _enable_action)
/\ v_role' = [v_role EXCEPT ![_node_id] = current_state]
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = current_voted_for]
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = current_term]
/\ UNCHANGED <<v_acked_value, v_log, v_snapshot, v_history, v_commit_index>>
)
[] result.append_result = APPEND_RESULT_TO_FOLLOWER -> (
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = current_term]
/\ v_role' = [v_role EXCEPT ![_node_id] = Follower]
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = INVALID_NODE_ID]
/\ SetAction(__action__, _setup_action, action_handle_append, _enable_action)
/\ UNCHANGED <<v_acked_value, v_log, v_snapshot, v_messages, v_history, v_commit_index>>
)
[] result.append_result = APPEND_RESULT_ACCEPT -> (
/\
LET \* TLA+ {D240524N- update commit index}
c_index ==
IF commit_index > v_commit_index[_node_id] THEN
IF commit_index <= result.match_index THEN
commit_index
ELSE
result.match_index
ELSE
v_commit_index[_node_id]
reply_payload == [
term |-> current_term,
append_success |-> TRUE,
match_index |-> result.match_index,
commit_index |-> c_index,
next_index |-> 0
]
reply_message == Message(_node_id, _from_node_id, AppendResponse, reply_payload)
output_action == Action(ActionOutput, reply_message)
IN (/\ v_commit_index' = [v_commit_index EXCEPT ![_node_id] = c_index]
/\ v_messages' = WithMessage(reply_message, v_messages)
/\ v_log' = [v_log EXCEPT ![_node_id] = result.log]
/\ IF c_index > v_commit_index[_node_id] THEN
\* update the commit index and acked values
/\ UpdateAckedValues(v_log'[_node_id], v_snapshot[_node_id], commit_index, _check_safety)
ELSE
UNCHANGED <<v_acked_value>>
/\ SetAction(__action__, _setup_action, action_handle_append \o output_action, _enable_action)
)
/\ (IF _check_safety
THEN (
LET leader_log == _payload.leader_log
leader_snapshot == _payload.leader_snapshot
op == [
follower_append |-> [
\*leader |-> _from_node_id,
\*message |-> _payload,
\*node_id |-> _node_id,
leader_log |-> leader_log,
leader_snapshot |-> leader_snapshot,
follower_log |->
IF Len(result.log) = 0 THEN
<<>>
ELSE
SubSeq(result.log, 1, result.match_index - v_snapshot[_node_id].index),
follower_snapshot |-> v_snapshot[_node_id]
]
]
IN v_history' = AppendHistory(v_history, op, _check_safety)
)
ELSE
UNCHANGED <<v_history>>
)
/\ v_role' = [v_role EXCEPT ![_node_id] = current_state]
/\ v_voted_for' = [v_voted_for EXCEPT ![_node_id] = current_voted_for]
/\ v_current_term' = [v_current_term EXCEPT ![_node_id] = current_term]
/\ UNCHANGED <<v_snapshot>>
)
[] OTHER -> (
FALSE
)
)
/\ UNCHANGED << v_follower_next_index, v_follower_match_index>>
Agree(_match_index, _index, _node_id, _v_conf_committed, _v_conf_new) ==
/\ LET _node_old == _v_conf_committed[_node_id].nid_vote
IN {_node_id} \cup
{
j \in _node_old :
/\ j /= _node_id
/\ _match_index[_node_id][j] >= _index
} \in QuorumOf(_node_old)
/\ (\/ _v_conf_new[_node_id] = _v_conf_committed[_node_id]
\/ LET _node_new == _v_conf_new[_node_id].nid_vote
IN {_node_id} \cup
{
j \in _node_new :
/\ j /= _node_id
/\ _match_index[_node_id][j] >= _index
} \in QuorumOf(_node_new)
)
AgreeIndex(_match_index, _v_log, _v_snapshot, _node_id, _v_conf_committed, _v_conf_new) ==
LET index_set == {_v_log[_node_id][j].index: j \in DOMAIN _v_log[_node_id]} \cup 1.._v_snapshot[_node_id].index
IN {i \in index_set : Agree(_match_index, i, _node_id, _v_conf_committed, _v_conf_new) }
_HandleAdvanceCommitIndex(
_match_index0, _v_log, _v_snapshot,
_v_conf_committed, _v_conf_new,
_node_id, _node_id_set, _check_safety
) ==
LET
\* the leader's last index is its match index
_match_index == [_match_index0 EXCEPT ![_node_id][_node_id] = LastLogIndex(_v_log[_node_id], _v_snapshot[_node_id])]
agree_indexes == AgreeIndex(_match_index, _v_log, _v_snapshot, _node_id, _v_conf_committed, _v_conf_new)
IN IF agree_indexes /= {} THEN
LET max_index == Max(agree_indexes)
IN (IF max_index > v_commit_index[_node_id] THEN
/\ v_commit_index' = [v_commit_index EXCEPT ![_node_id] = max_index]
/\ UpdateAckedValues(v_log[_node_id], v_snapshot[_node_id], max_index, _check_safety)
ELSE
UNCHANGED <<v_acked_value, v_commit_index>>
)
ELSE
UNCHANGED <<v_acked_value, v_commit_index>>
_HandleAppendLogResponse(_node_id, _source, _payload, _node_id_set, _check_safety) ==
LET term_context == _UpdateTerm(_node_id, _payload.term)
IN /\ ( IF term_context.state = Leader