build.gradle

allprojects {
    version = "1.0.0"
    apply plugin: "java"
}

subprojects {
    apply plugin: "java"
    apply plugin: "jacoco"
    apply plugin: "maven"
    apply plugin: "maven-publish"

    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8

    [compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

    buildscript {
        repositories {
            mavenCentral()
            maven { url 'https://jitpack.io' }
            maven {
                url "https://plugins.gradle.org/m2/"
            }
        }
        dependencies {
            classpath 'com.google.protobuf:protobuf-gradle-plugin:0.9.1'
            classpath "gradle.plugin.com.github.johnrengelman:shadow:7.1.2"
        }
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url 'https://repo.spring.io/plugins-release' }
        maven { url 'https://jitpack.io' }
    }

    dependencies {
        compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
        compile group: 'org.slf4j', name: 'jcl-over-slf4j', version: '1.7.25'
        compile group: 'ch.qos.logback', name: 'logback-classic', version: '1.2.9'
        compile group: 'com.google.guava', name: 'guava', version: '30.1-jre'
        compile "com.google.code.findbugs:jsr305:3.0.0"
        compile group: 'org.springframework', name: 'spring-context', version: '5.3.18'
        compile group: 'org.springframework', name: 'spring-tx', version: '5.3.18'
        compile "org.apache.commons:commons-lang3:3.4"
        compile group: 'org.apache.commons', name: 'commons-math', version: '2.2'
        compile "org.apache.commons:commons-collections4:4.1"
        compile group: 'joda-time', name: 'joda-time', version: '2.3'
        compile group: 'org.bouncycastle', name: 'bcprov-jdk15on', version: '1.69'

        compileOnly 'org.projectlombok:lombok:1.18.12'
        annotationProcessor 'org.projectlombok:lombok:1.18.12'
        testCompileOnly 'org.projectlombok:lombok:1.18.12'
        testAnnotationProcessor 'org.projectlombok:lombok:1.18.12'

        testImplementation group: 'junit', name: 'junit', version: '4.13.2'
        testImplementation "org.mockito:mockito-core:2.1.0"
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = "sources"
        from sourceSets.main.allSource
    }


    tasks.withType(AbstractArchiveTask) {
        preserveFileTimestamps = false
        reproducibleFileOrder = true
    }

    configurations.all {
        resolutionStrategy {
            force group: 'com.google.guava', name: 'guava', version: '30.1-jre'
        }
    }
}

task copyToParent(type: Copy) {
    into "$buildDir/libs"
    subprojects {
        from tasks.withType(Jar)
    }
}

build.finalizedBy(copyToParent)

gradle.buildFinished {
    if (project.hasProperty('cleanSubBuild')) {
        subprojects {
            buildDir.deleteDir()
        }
    }
}